
 1000  *SAVE S.READ.TIME+
 1010  *--------------------------------
 1020  *   READ TIMEMASTER H.O. CARD, PUTTING
 1030  *      TIME INTO APPLESOFT STRING TI$.
 1040  *--------------------------------
 1050  *   BY BOB SANDER-CEDERLOF
 1060  *--------------------------------
 1070  VARNAM .EQ $81,82
 1080  FORPNT .EQ $85,86
 1090  *--------------------------------
 1100  WBUF   .EQ $200
 1110  *--------------------------------
 1120  SLOT   .EQ 5      <<<BE SURE TO PUT YOUR SLOT HERE>>>
 1130  *--------------------------------
 1140  AS.GDBUFS  .EQ $D539     MARK END, CLEAR HI-BITS
 1150  AS.SAVD    .EQ $DA9A     FINISH INSTALLING STRING
 1160  AS.PTRGET9 .EQ $E04F     FIND OR MAKE VARIABLE
 1170  AS.STRLIT  .EQ $E3E7     BUILD STRING DESCRIPTOR
 1180  *--------------------------------
 1190         .OR $300     (WHERE ELSE!)
 1200  *--------------------------------
 1210  RDTIME
 1220         LDA #"%"     MODE: "FRI JAN 03 10:11:32 AM"
 1230         JSR SLOT*256+$C00B
 1240         JSR SLOT*256+$C008  READ TIME STRING
 1250  *---PREPARE STRING FOR A/S-------
 1260         LDX #23      LENGTH OF STRING
 1270         JSR AS.GDBUFS     CLEAR HI-BITS AND MARK END
 1280  *---SETUP TI$ VARIABLE-----------
 1290         LDA #'T'     HI-BIT OFF FOR STRING VARIABLE
 1300         STA VARNAM
 1310         LDA #"I"     HI-BIT ON FOR STRING VARIABLE
 1320         STA VARNAM+1
 1330         JSR AS.PTRGET9
 1340         STA FORPNT
 1350         STY FORPNT+1
 1360  *---MOVE TIME INTO TI$-----------
 1370         LDA #WBUF+1  SKIP OVER LEADING QUOTE
 1380         LDY /WBUF+1
 1390         JSR AS.STRLIT
 1400         JMP AS.SAVD  CLEAN UP STRINGS AND RETURN
 1410  *--------------------------------

